error-handling - VBScript - 验证输入是 IP，每八位字节 3 位

Question

我是一名学习 VBScript 的学生。就在几天前[笑着说]，我刚开始用 BASIC、DOS 和机器码编程，所以基本概念并不陌生，只是有点。

警告 - 这是评分作业的一部分，主要要求的是对代码的指导和理解。

尝试为用户输入 IP 地址编写脚本，其中每个八位字节为 3 位格式（必要时前导零）。这是起始输入

' Get IP address to convert
WScript.StdOut.Write("Please Enter your IP address (3 digits per octet) -> ")
strIP = WScript.StdIn.ReadLine()

试图进行错误检查并遇到问题。尝试了各种方法，但似乎都没有提供所需的输出，如果在运行时没有失败并出现各种 VBScript 错误。

版本 1：

Dim sMatch(15)
if sMatch = strIP Like "###.###.###.###" Then
   Wscript.Echo "The strings are equal."
Else
   Wscript.Echo "The strings are not equal."
' WScript.Echo sMatch
End If

版本 2：

String str = StrComp("strIP", ""\###.\###.\###.\###"",vbTextCompare)
If str < 0 or str > 0 then WScript.StdOut.WriteLine "Improper IP format."

版本 3：

iFirstOct = Left(strIP,3)

z1 = strComp(iFirstOct, "###", 1)
WScript.Echo "z1 -> " & z1
WScript.Echo "IP -> " & iFirstOct
If z1 < 1 or z1 > 1 Then 
  WScript.Echo " Error in input !" 
  WScript.quit
End If

我有点喜欢版本 3，因为我可以对它进行子程序化，但不确定哪个是可行的选择。任何帮助确定我在哪里出错以及如何出错，将不胜感激。

警告 - 这是评分作业的一部分，主要要求的是对代码的指导和理解。

-- 编辑 - 21 年 2 月 16 日 --

艾蒂安，

这是最终的脚本。我已经运行了不同的错误场景，它似乎按照我需要的方式运行。谢谢您的帮助。

' IP_func.vbs
'
'  By: Étienne Laneville
'    Minor modifications by DragonRider
'  From: https://stackoverflow.com/questions/66177237/vbscript-verify-input-is-ip-3-digits-per-octet
'
'
WScript.StdOut.Write("Please Enter your IP address (3 digits per octet) -> ")
strIP = WScript.StdIn.ReadLine()
WScript.Echo vbCrLf & " Input -> " & vbTab & strIP & vbCrlf

' Call error-checking function
CheckIP(strIP)


Function CheckIP(strIP)
    Dim arrOctets
    Dim iCounter
    Dim sOctet
    
    ' Check for periods
    If InStr(strIP, ".") = 0 Then
        CheckIP = False
        WScript.Echo " Incorrect number of octets. Please try again."
        Exit Function 
    End If

    ' Split string on periods
    arrOctets = Split(strIP, ".")
    
    ' Check that correct number of octets has been received
    If UBound(arrOctets) <> 3 Then
        CheckIP = False
        WScript.Echo " Incorrect number of octets. Please try again."
        Exit Function
    End If
    
    ' Check each octet
    For iCounter = 1 To 4
        
        sOctet = arrOctets(iCounter - 1)
        
        ' Check if it's numeric
        If Not IsNumeric(sOctet) Then
            CheckIP = False
            WScript.Echo " Improper IP Address. Please try again."
            Exit Function
        End If
        
        ' Check if 3 digits
'        Dim three As String
        If Not Len(sOctet) = 3 Then
            CheckIP = False
            WScript.Echo " 3-Digits per octet. Please try again."
            Exit Function
        End If
        
        ' Check for proper values
        If CInt(sOctet) > 255 Then
            CheckIP = False
            WScript.Echo " Octet out of range. Please try again."
            Exit Function
        End If
        
        If CInt(sOctet) < 0 Then
            CheckIP = False
            WScript.Echo " Improper IP Address. Please try again."
            Exit Function
        End If
        
    Next
        
    CheckIP = True

End Function

标签： error-handlingvbscriptip-addresscustom-error-handling

Answer 1

这是一个简单的函数，可以将事情分解为简单的操作：

Function CheckIP(strIP)
    Dim arrOctets
    Dim iCounter
    Dim sOctet
    
    ' Check for periods
    If InStr(strIP, ".") = 0 Then
        CheckIP = False
        Exit Function
    End If

    ' Split string on periods
    arrOctets = Split(strIP, ".")
    
    ' Check that correct number of octets has been received
    If UBound(arrOctets) <> 3 Then
        CheckIP = False
        Exit Function
    End If
    
    ' Check each octet
    For iCounter = 1 To 4
        
        sOctet = arrOctets(iCounter - 1)
        
        ' Check if it's numeric
        If Not IsNumeric(sOctet) Then
            CheckIP = False
            Exit Function
        End If
        
        ' Check for proper values
        If CInt(sOctet) > 255 Then
            CheckIP = False
            Exit Function
        End If
        
        If CInt(sOctet) < 0 Then
            CheckIP = False
            Exit Function
        End If
        
    Next
        
    CheckIP = True

End Function