时间戳

首页 > 解决方案 > 在 Drools 中获取相似的对象

drools - 在 Drools 中获取相似的对象

问题描述

假设我有一个衬衫类型的对象列表，并且每件衬衫都有一个颜色属性。有没有办法创建一个规则，只得到相同颜色的衬衫（不管是什么颜色）？

标签： drools

解决方案

您正在寻找collect功能。（链接是 Drools 文档，向下滚动一点以找到“收集”。）就像它的名字所示，它收集符合条件的东西。

让我们假设一个Shirt带有 Stringcolor变量的简单类。我们还假设工作记忆中有各种衬衫实例。

rule "Collect shirts by color"
when
  Shirt( $color: color )
  $shirts: List() from collect( Shirt( color === $color ) )
then
  // $shirts will now contain all shirts of $color
end

此规则将单独考虑每件衬衫，然后收集具有相同颜色的所有其他衬衫。因此，如果您有红色、蓝色和绿色衬衫，您将至少在右侧输入一次$shirts该单一颜色的衬衫。

当然，这里的问题是您将基于每件衬衫而不是基于每种颜色触发规则。因此，如果您有两件红色衬衫，您将触发所有红色衬衫的“then”子句两次（每件红色衬衫一次，因为每件红色衬衫将独立满足第一个条件。）

如果您不介意这一点，那么您可以按原样使用它。但是，如果您只想让您的结果在每种衬衫颜色中触发一次，我们必须更加狡猾。

为了让颜色成为一等公民，我们需要提取衬衫颜色的不同集合（不是列表！），然后根据需要使用这些来收集我们的列表。这里我使用accumulate函数；您可以在我之前分享到 Drools 文档的同一链接上阅读更多相关信息（accumulate直接在 之后collect。）

rule "Get shirt colors"
when
  // Get all unique shirt colors
  $colors: Set() from accumulate( Shirt( $color: color), collectSet( $color ))

  // Get one of those colors
  $color: String() from $colors

  // Find all shirts of that color
  $shirts: List() from collect( Shirt( color === $color ) )
then
  // $shirts is all shirts of $color
end

在第二条规则中，每种颜色只能触发一次右侧，因为我们首先将所有可能的颜色提炼成一组独特的颜色。

反之则更简单。如果您需要做的只是确认至少有一件颜色不同的衬衫，我们只需要获取所有颜色并验证至少存在 2 种不同颜色。

rule "At least one shirt of a different color"
when
  $colors: Set( size > 1 ) from accumulate( 
    Shirt( $color: color), 
    collectSet( $color )
  )
then
  // $colors contains more than 1 color, so there's at
  // least 1 shirt present that is not the same color
  // as the rest
end

推荐阅读