for-loop - Findstr 在 UNC 批处理脚本上太慢了

问题描述

我正在运行一个遍历网络文件夹并保存找到的文件的脚本，但是运行时间太长。我已经尝试将 findstr 隔离到一个文件夹中，并且它在正常的时间运行，所以我认为它与 FOR 循环有关。

@echo off

setlocal

set SERVERS=server1 server2 server3 server4

cls
echo Type below the query parameters:
set /p year=Year (4 digits): 
set /p month=Month (2 digits): 
set /p day=Day (2 digits): 
set /p query=Query string: 
cls
echo Results:
del /F /Q "C:\Users\%USERNAME%\Desktop\found_files\*" 2>nul
if not exist "C:\Users\%USERNAME%\Desktop\found_files" mkdir "C:\Users\%USERNAME%\Desktop\found_files"
for /f "tokens=*" %%a in ('for %%i in ^(%SERVERS%^) do @findstr /S /I /M /C:"%query%" "\\%%i\folder_structure\*%year%-%month%-%day%*.xml"') do copy /Y "%%a" "C:\Users\%USERNAME%\Desktop\found_files" >nul & echo %%a & set found=1
echo.
if "%found%"=="1" (
    echo File^(s^) saved successfully!
) else (
    echo No files found!
)
echo.
pause
if "%found%"=="1" explorer C:\Users\%USERNAME%\Desktop\found_files

标签： for-loopbatch-filefindstrunc

您的脚本已经优化得很好。我不认为你可以做很多事情来加快速度。

我怀疑你的问题是FINDSTR在你的本地机器上运行，它必须扫描所有 UNC 路径上的文件（几乎肯定不是本地的）。这意味着每个文件的全部内容必须通过您的网络传输。如果你的系统和我工作的地方一样，那可能是一场噩梦。我们的网络驱动器性能很差（比本地驱动器慢 100 倍以上）！

Squashman（和SomethingDark）有点担心你的外部FOR /F执行嵌套FOR语句。但我相信这是最有效的方法。当FOR /F迭代命令输出时，它必须启动一个新进程来执行命令。您当前的脚本只需要一个子进程。

更“传统”的方法是将%SERVERS%迭代移到内部循环之外，如下所示：

for %%i in (%SERVERS%) do for /f "tokens=*" %%a in (
  'findstr /S /I /M /C:"%query%" "\\%%i\folder_structure\*%year%-%month%-%day%*.xml"'
) do copy /Y "%%a" "C:\Users\%USERNAME%\Desktop\found_files" >nul & echo %%a & set found=1

但这实际上效率较低，因为它必须为%SERVERS%. 话虽如此，与通过网络传输文件内容的实际瓶颈相比，我认为差异并不显着。

为了显示 1 与 100 个子流程的影响，我对以下逻辑等效（但无意义）的命令进行了快速比较：

for /f "delims=" %%F in (
  'for /l %%N in ^(1 1 100^) do @findstr /m "^" *'
) do echo %%F>nul
:: This took 39 seconds on my machine

for /l %%N in (1 1 100) do for /f %%F in (
  'findstr /m "^" *'
) do echo %%F>nul
:: This took 60.9 seconds on my machine

for-loop - Findstr 在 UNC 批处理脚本上太慢了

问题描述

解决方案

推荐阅读