gnuplot - gnuplot 自动堆栈条形图
问题描述
这是我的数据集:
type size name
label_0 1 nameOfData_0
label_0 2 nameOfData_1
label_0 3 nameOfData_2
label_1 2 nameOfData_3
label_2 1 nameOfData_4
label_0 2 nameOfData_5
label_1 3 nameOfData_6
label_3 2 nameOfData_7
label_3 1 nameOfData_8
我希望情节看起来像:
我希望每个标签都是一个堆栈,并且每个 nameOfData_X 根据其大小适合正确的堆栈。如果可能,还为堆栈的每个元素添加图例。
我知道我可以重新格式化数据以通过 gnuplot 轻松处理它,但我不想这样做。
关于如何通过 gnuplot 显示此图的任何想法?
谢谢你的帮助!
解决方案
也许有一种方法可以使用 gnuplot 内置的堆叠直方图样式来实现这一点,检查help histograms
。以下解决方案不是太明显,但似乎给出了预期的结果并使用了绘图样式with boxxyerror
(检查help boxxyerror
)。
- 您需要第 1 列的唯一元素列表。这里将按照第一次出现的顺序排列。
- 在循环绘图期间,您根据“过滤器”功能添加您的贡献
myAdd()
。 - 当加法为零时更改颜色(
dy=0
)。 - 您以类似的方式添加带有偏移量的标签
此代码可能可以简化,但可以作为起点。
代码:
### "manual" stacked histogram
reset session
$Data <<EOD
type size name
label_0 1 nameOfData_0
label_0 2 nameOfData_1
label_0 3 nameOfData_2
label_1 2 nameOfData_3
label_2 1 nameOfData_4
label_0 2 nameOfData_5
label_1 3 nameOfData_6
label_3 2 nameOfData_7
label_3 1 nameOfData_8
EOD
# get a unique list from datablock column 1
set table $Dummy
Headers = 1
addToList(list,col) = list.( strstrt(list,'"'.strcol(col).'"') > 0 ? '' : \
' "'.strcol(col).'"')
plot Uniques='' $Data u (Uniques=addToList(Uniques,1),'') skip Headers w table
unset table
N = words(Uniques)
Unique(i) = word(Uniques,i)
set xrange [1:N]
set xtics out noenhanced
set grid x,y
set offsets 0.5,0.5,0.5,0
unset key
set style fill transparent solid 0.7 border
myBoxWidth = 0.8
myAdd(colD,colF,i) = strcol(colF) eq Unique(i) ? column(colD) : 0
myLabel(col1,col2) = dy==0 ? '' : sprintf("%s\n%g",strcol(col1),column(col2))
plot for [i=1:N] y=y0=(c=1,0) $Data u (i):(dy=myAdd(2,1,i), y=y+dy,(y0+y)/2.): \
(myBoxWidth/2.):(y0=y,dy/2.):(dy==0?c:c=c+1) skip Headers w boxxy lc variable, \
for [i=1:N] y=y0=0 $Data u (i):(dy=myAdd(2,1,i), y=y+dy,(y0+y)/2.): \
(y0=y,myLabel(3,2)):xtic(Unique(i)) skip Headers w labels offset 0,0.5 noenhanced
### end of code
结果:
推荐阅读
- c# - C# - jQuery 1.8.0 扩展方法问题
- r - 自制功能在测试中有效,但不适用于我的实际数据集
- r - 在使用 expand.grid 计算距离矩阵之前按变量对数据集进行子集
- python - Python 密码拒绝验证
- tensorflow - 如何解决回归模型中张量流中的非损失问题
- oracle - Oracle - 需要使用 CONTAINS 来查找包含句点的字符串
- excel - VBA 从 Excel 工作簿和 .sql 文件写入动态查询
- javascript - 文本锚不会出现在 D3 中
- wcf - WCF、MSMQ 和 2 个队列上的独立事务
- sql-server - SQL Server 的并排行