时间戳

首页 > 解决方案 > 图形的密码查询

neo4j - 图形的密码查询

问题描述

如何确定图的每个节点的入度和出度以及总度数。此外，图的最长路径是图的直径和图的密度。最后两个问题是每种类型的关系数，以及每个标签的节点数。

我的数据集如下所示：在此处输入图像描述

我使用这个查询来加载数据集：

LOAD CSV WITH HEADERS FROM 'file:///vgsales.csv' AS line 
CREATE (v:Vgsales {
  rank: toInteger(line.Rank),
  name: line.Name,
  platform: line.Platform,
  year: toInteger(line.Year)
}) 
MERGE (g:GENRE {genre: line.Genre}) 
MERGE (p:PUBLISHER {
  publisher: line.Publisher,
  NA_sales: toInteger(line.NA_Sales), 
  EU_sales: toInteger(line.EU_Sales),
  JP_sales: toInteger(line.JP_Sales),
  Other_sales: toInteger(line.Other_Sales),
  Global_sales: toInteger(line.Global_Sales)
}) 
MERGE (v)-[:IN_GENRE]->(g) 
MERGE (p)-[:PUBLISHED]->(v)

标签： neo4jcypher

解决方案

对于一个节点，您可以使用它size(<pattern>)来查找模式的程度（前提是没有为另一个节点提供标签，并且模式中不存在任何属性，因为这些属性实际上需要扩展路径以查找和过滤这些东西）。

因此，要获取图中所有节点的所有进出度，您可以使用：

MATCH (n)
RETURN id(n) as id, size((n)-->()) as outDegree, size((n)<--()) as inDegree

图的直径是每个节点之间所有最短路径中最长的，因此要求两个节点的每个组合首先得到最短路径，然后只取最长的：

MATCH (n)
WITH collect(n) as allNodes
UNWIND allNodes as a
UNWIND allNodes as b
WITH a, b
WHERE id(a) < id(b)
MATCH path = shortestPath((a)-[*]-(b))
RETURN max(length(path)) as diameter

限制是确保我们过滤掉 a 和 b 是相同节点的id(a) < id(b)行，并过滤掉镜像结果，因为我们只需要 a 和 b 的单个组合（并且在交换 a 和 b 时不计算第二次） .

对于每个关系的计数，以及按标签的节点计数，这些都存储在计数存储中，访问这些统计信息的最简单方法是通过 APOC 过程。这可以预先捆绑，请查看此安装页面（更改您在 url 中使用的次要版本以获取更具体的说明）：

https://neo4j.com/labs/apoc/4.1/installation/

安装后，您可以使用它CALL apoc.meta.stats()来访问所有图形计数。该nodeCount列将为您提供图表中的总节点，该labels列将为您提供每个标签的计数。该relTypesCount列将为您提供每种关系类型的计数。

我相信对于图密度，对于有向图，它是E / (V (V - 1))，其中 E 是总边，V 是总顶点。我们可以从计数存储中获取这些并使用该公式：

CALL apoc.meta.stats() YIELD nodeCount, relCount
RETURN toFloat(relCount) / (nodeCount * (nodeCount - 1)) as density

推荐阅读