时间戳

首页 > 解决方案 > 如何批量请求管理员权限？

batch-file - 如何批量请求管理员权限？

问题描述

几周以来，我修改 IP 地址的脚本不再起作用。我怀疑 Windows 10 的更新。

到目前为止，我使用的是这个线程中给出的脚本：

@echo on

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
    IF "%PROCESSOR_ARCHITECTURE%" EQU "amd64" (
>nul 2>&1 "%SYSTEMROOT%\SysWOW64\cacls.exe" "%SYSTEMROOT%\SysWOW64\config\system"
) ELSE (
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
)

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params= %*
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params:"=""%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------    
    <YOUR BATCH SCRIPT HERE>

但是现在，我得到了这个错误：

加载脚本失败：C:\Users\me\AppData\Local\Temp\getadmin.vbs：访问被拒绝

奇怪的是，getadmin.vbs 确实是在 Temp 目录下创建的。

这是确切的输出：

C:\Users\arc\Desktop\ConfigLAN>REM --> Check for permissions

C:\Users\arc\Desktop\ConfigLAN>IF "AMD64" EQU "amd64" ("C:\WINDOWS\SysWOW64\cacls.exe" "C:\WINDOWS\SysWOW64\config\system" 1>nul 2>&1 ) ELSE ("C:\WINDOWS\system32\cacls.exe" "C:\WINDOWS\system32\config\system" 1>nul 2>&1 )

C:\Users\arc\Desktop\ConfigLAN>REM --> If error flag set, we do not have admin.

C:\Users\arc\Desktop\ConfigLAN>if '5' NEQ '0' ( echo Requesting administrative privileges... goto UACPrompt ) else (goto gotAdmin ) Requesting administrative privileges...

C:\Users\arc\Desktop\ConfigLAN>echo Set UAC = CreateObject("Shell.Application") 1>"C:\Users\arc\AppData\Local\Temp\getadmin.vbs"

C:\Users\arc\Desktop\ConfigLAN>set params=

C:\Users\arc\Desktop\ConfigLAN>echo UAC.ShellExecute "cmd.exe", "/c ""C:\Users\arc\Desktop\CONFIG~1\newBatch.bat"" ", "", "runas", 1 1>>"C:\Users\arc\AppData\Local\Temp\getadmin.vbs"

C:\Users\arc\Desktop\ConfigLAN>"C:\Users\arc\AppData\Local\Temp\getadmin.vbs"

(error is triggered here)

C:\Users\arc\Desktop\ConfigLAN>del "C:\Users\arc\AppData\Local\Temp\getadmin.vbs"

C:\Users\arc\Desktop\ConfigLAN>exit /B

标签： batch-filewindows-10admin

解决方案

您可以使用以下对我来说非常有效的序列。

@echo off
::::::::::::::::::::::::::::::::::::::::::::
:checkPrivileges
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' (goto gotPrivileges) else (goto getPrivileges)
:getPrivileges
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo For Each strArg in WScript.Arguments >> "%temp%\getadmin.vbs"
echo If strArg = WScript.Arguments.Item^(0^) Then d = Left^(strArg, InStrRev^(strArg,"\"^) - 1^) >> "%temp%\getadmin.vbs"
echo args = args ^& " " ^& strArg  >> "%temp%\getadmin.vbs"
echo Next >> "%temp%\getadmin.vbs"
echo UAC.ShellExecute "cmd.exe", ^("/c start /D """ ^& d ^& """ /B" ^& args ^& " ^& exit"^), , "runas", 4 >> "%temp%\getadmin.vbs"
cscript "%temp%\getadmin.vbs" ""%~s0"" %*
del /q "%temp%\getadmin.vbs"
exit /b
:gotPrivileges
:: Your code here

这个 VBS 脚本完美地使用了 UAC.ShellExecute，您可以自己指出更改。您使用了很多技巧，VBS 代码甚至没有以正确的方式调用 UAC，这就是它拒绝权限的原因。我相信在过去使用 cacls 和这个脚本非常有用，被恶意软件用来在未经用户许可的情况下获得管理访问权限，有很多程序为此使用 icacls，我什至不会指出，但可能有使使用 icacls 变得困难。

您也可以以前使用 Powershell 来执行此操作。

Powershell -Command "Start-Process cmd -Verb RunAs -ArgumentList '/c C:\YourPath\yourprogram.bat'"

这两个脚本对我来说都很好。我可以在您的 .vbs 中看到很多错误，但是指出它们是没有意义的，因为脚本不是您的。我建议您使用 Powershell，它更有用且更简单，可以集成：

NET FILE >NUL 1>NUL 2>NUL
if %errorlevel% equ 0 (goto gotprivileges) else (start Powershell -Command "Start-Process cmd -Verb RunAs -ArgumentList '/c C:\YourPath\yourprogram.bat'" & exit)

希望这会有所帮助，
K。

推荐阅读