时间戳

首页 > 解决方案 > Word VBA - 在新文档中复制粘贴图像标题

vba - Word VBA - 在新文档中复制粘贴图像标题

问题描述

我有一个将指定表格复制到新文档中的功能，但我不知道如何导出作为图像的页眉，并将其设置为文档页面的页眉。

该表是根据组合框 (ProjectsList.Value) 的实际值选择的，它指的是一个书签，其中包含的表被成功复制粘贴到一个新文档中

对于每个粘贴的页面，我也想复制标题。

我将在其中集成标题部分的功能：

Sub CopyPaste()
Dim Source As Document
Dim Target As Document
Dim tbl As Table
Dim tr As Range
Dim hRange As Word.Range

Set Source = ActiveDocument
Set Target = Documents.Add
Target.SaveAs FileName:=ProjectsList.Value

For Each tbl In Source.Bookmarks(ProjectsList.Value).Range.Tables
    Set tr = Target.Range
    tr.Collapse wdCollapseEnd
    tr.FormattedText = tbl.Range.FormattedText
    tr.Collapse wdCollapseEnd
    tr.Text = vbCrLf
Next

End Sub

标签： vbams-wordheaderms-officebookmarks

解决方案

例如：

Sub Replicate()
Application.ScreenUpdating = False
Dim Source As Document, Target As Document
Dim Tbl As Table, HdFt As HeaderFooter, Rng As Range
Set Source = ActiveDocument: Set Target = Documents.Add
With Target
    For Each Tbl In Source.Bookmarks(ProjectsList.Value).Range.Tables
        Set Rng = .Range.Characters.Last
        Rng.FormattedText = Tbl.Range.FormattedText
        Rng.InsertAfter vbCr
    Next
    For Each HdFt In Source.Sections.First.Headers
        With HdFt
            Set Rng = Target.Sections.First.Headers(.Index).Range
            Rng.FormattedText = .Range.FormattedText
            Rng.Characters.Last.Delete
        End With
    Next
    .SaveAs FileName:=ProjectsList.Value
End With
Application.ScreenUpdating = True
End Sub

推荐阅读