amazon-web-services - Terraform - 循环遍历对象列表的动态块

Question

我正在尝试配置此 Terraform，以便添加新的 SG 入口规则所需要做的就是向.tfvars文件添加一个块，新的入口规则将添加到单个 SG。

我有一个.tfvars看起来像这样的文件：

rules = [
  {
    protocol = "tcp"
    port = 22
    cidr = ["10.0.0.0/8"],
  },
  {
    protocol = "tcp"
    port = 80
    cidr = ["10.0.0.0/8"]
  },
  {
    protocol = "tcp"
    port = 443
    cidr = ["10.0.0.0/8"]
  },
  {
    protocol = "icmp"
    port = -1
    cidr = ["10.0.0.0/8"]
  }
]

我的 Terraform 是：

variable "rules" {
  type = list(object({
    protocol = string
    port = number
    cidr = list(string)
  }))
  description = "Specify the protocol, port range, and CIDRs."
}


resource "aws_security_group" "this" {
...

dynamic "ingress" {
  for_each = { for rule in var.rules : rule.id => rule }

  content {
    from_port   = var.rules.port
    to_port     = var.rules.port
    protocol    = var.rules.protocol
    cidr_blocks = var.rules.cidr
  }
}

...

我尝试遍历上述内容，也尝试使用 usingfor_each = var.rules但我只是收到以下错误（发生在以下每个错误中）：

protocol     = var.rules.protocol
from_port    = var.rules.port
to_port      = var.rules.port
cidr_blocks  = var.rules.cidr
-----------------------------
var.rules is list of object with 4 elements. 
This value does not have any attributes.`

我有点卡住了，不知道还能尝试什么，所以有人有什么想法吗？

标签： amazon-web-servicesloopsdynamicterraform

Answer 1

这里有几个问题。第一个是在您的for_each元参数值for表达式 lambda 中，您正试图访问一个不存在的对象键id. 此外，您可以轻松地在list(object)此处使用 a 而不是map(object)您在转换中尝试执行的操作，然后可以直接使用您的输入变量。我们可以丢弃这些并相应地固定值：

for_each = var.rules

第二个问题是动态块中的临时 lambda 迭代器变量是块本身的名称。在这种情况下，您的块被命名为ingress. 因此，我们需要从它的对象键中访问值：

content {
  from_port   = ingress.value.port
  to_port     = ingress.value.port
  protocol    = ingress.value.protocol
  cidr_blocks = ingress.value.cidr
}

结合这些修复，我们得出：

dynamic "ingress" {
  for_each = var.rules

  content {
    from_port   = ingress.value.port
    to_port     = ingress.value.port
    protocol    = ingress.value.protocol
    cidr_blocks = ingress.value.cidr
  }
}