时间戳

首页 > 解决方案 > 如何在球拍的正方形内找到一个点？

racket - 如何在球拍的正方形内找到一个点？

问题描述

目前，我正在努力找出一个函数，该函数可以确定一个点是否在正方形中，或者没有给定正方形的边长和左上角。

; tl is a Posn, giving the top-left corner of the square
; side is a Number, giving the side length of the square
(define-struct SQ (tl side))
(define z (make-SQ tl side))
(define x (+ (posn-x SQ-tl z) (SQ-side z)))
(define y (+ (posn-y SQ-tl z) (SQ-side z)))
(define a (make-posn x y))
; Posn, SQ -> Boolean
(define (point-in-square? P S)  (and (<= (posn-x P) (posn-x a) S)
                                     (>= (posn-x P) (posn-x (SQ-tl z)) S)
                                     (<= (posn-y P) (posn-y a) S)
                                     (>= (posn-y P) (posn-y (SQ-tl z)) S)))

我收到错误 tl: undefined; cannot reference undefined identifier 我将如何解决此错误？

标签： racketcomputer-science

解决方案

最初的问题导致错误，例如：tl: undefined; cannot reference undefined identifier. 在构造一个 square 的调用中，构造z函数make-SQ是用参数tl和side;调用的。但尚未为这些标识符分配任何值。似乎 OP 正在使用它们，因为这些是插槽名称；构造函数需要适当的值来分配给插槽。这里的解决方案只是认识到实际SQ实例的构造需要具体值。

克服第一个障碍清楚地表明point-in-square?谓词的定义有问题。该定义试图使用全局定义的z正方形和a点。但是这个过程也需要P和S参数，它们分别是一个点和一个正方形。这是解决问题所需的所有信息。

在解决了评论中与 OP 相关的问题后，OP 已经解决了问题以使代码正常工作。这是一个替代解决方案，用于let*使代码更易于阅读和思考：

#lang racket

(define-struct posn (x y))

(define-struct SQ (tl side))

(define (point-in-square? P S)
  (let* ((top-left (SQ-tl S))
         (side-length (SQ-side S))
         (left (posn-x top-left))
         (right (+ left side-length))
         (top (posn-y top-left))
         (bottom (+ top side-length)))
    (and (<= (posn-x P) right)
         (>= (posn-x P) left)
         (<= (posn-y P) bottom)
         (>= (posn-y P) top))))

还有一个示例 REPL 交互：

point-in-square.rkt> (define test-square (make-SQ (make-posn 4 2) 1))
point-in-square.rkt> (define p1 (make-posn 5 3))  ; in square
point-in-square.rkt> (define p2 (make-posn 5 2))  ; on edge of square
point-in-square.rkt> (define p3 (make-posn 5 1))  ; not in square
point-in-square.rkt> (point-in-square? p1 test-square)
#t
point-in-square.rkt> (point-in-square? p2 test-square)
#t
point-in-square.rkt> (point-in-square? p3 test-square)
#f

请注意，这let对于将计算中使用的值绑定到有意义的名称很有用；在这种情况下，let*它很方便，因为它允许我们在后续绑定中使用先前以相同let*形式绑定的值。另一种方法是嵌套let表单，以便内部lets 可以使用外部绑定。

推荐阅读