时间戳

首页 > 解决方案 > 理解 Perl 包的命名空间

perl - 理解 Perl 包的命名空间

问题描述

考虑这个脚本（从我拥有的更大的脚本中总结出来）：

#!/usr/bin/perl

use strict;
use warnings;

package help {
    my %HELPTEXT;
    $HELPTEXT{ "topic" } = "Some help\n";

    sub get_help( $ ) {
        print $HELPTEXT{ $_[0] };
    }
}

package main {
    sub main() {
        help::get_help( "topic" );
    }
}

main();

这有效，打印Some help。

现在，我想将初始化（$HELPTEXT{ "topic" } = "Some help\n";和其他类似的）放在脚本的末尾——同时保留package help它的代码。

但是，这不起作用：

# ...
main();

package help {
    $HELPTEXT{ "topic" } = "Some help";
}

错误信息：Global symbol "%HELPTEXT" requires explicit package name (did you forget to declare "my %HELPTEXT"?)

这也不起作用：

main();

$help::HELPTEXT{ "topic" } = "Some help\n";

错误信息：Name "help::HELPTEXT" only used once/ Use of uninitialized value in print。

显然我缺乏对 Perl 包及其命名空间的理解。

我可以在中间文件包命名空间中有一个变量，并且仍然在文件末尾初始化它吗？

补充：我发现声明问题可以通过以下方式解决our：

# ...
main();

package help {
    our %HELPTEXT;
    $HELPTEXT{ "topic" } = "Some help\n";
}

来自 perldoc：

"our" 为当前包中同名的包（即全局）变量创建一个词法别名，以便在当前词法范围内使用。

但是，这仍然给出一个错误：Use of uninitialized value in print。即使我将初始化包装在一个INIT {}块中。

我不仅想为此提供解决方案，而且还想了解为什么它不能按我预期的那样工作。通过猜测编码感觉很糟糕......

标签： perlpackageinitialization

解决方案

这里有几件事要理解，我在Learning Perl中写了很多关于这点的内容。其中大部分是意识到词法变量和包变量是两个不同的系统。任何词汇都不关心默认包是什么。

这是您strict失败的示例：

use v5.12;
use strict;

package help {
    $HELPTEXT{ "topic" } = "Some help";
}

use strict适用于您使用它的任何范围（文件或块）。在该范围内，您必须在首次使用时声明变量或使用完整的包规范。由于您都没有这样做，因此您会收到错误消息。更改包装不会将其关闭。

该package声明仅更改默认包名称。使用块形式，它只会更改该块中的默认包。任何词汇都不关心，包括词汇变量。这$foo并不关心默认包是什么，因为它不是包变量。无论默认包是什么，它都会持续到范围（块或文件）结束：

use v5.12;
use strict;
use warnings;

package help;

my $foo = 'bar';

package main;

say $foo;  # outputs bar

our当您在同一范围内组合包时，使用相反会产生奇怪的效果。您将获得一个具有该名称的词法变量，该变量在范围内的任何位置都可用，并且您将获得一个具有该名称的包变量（在程序中的任何位置都可用）。它们使用相同的数据，因此更改任何一个都会更改数据，并且两个版本都表明：

use v5.12;
use strict;
use warnings;

package help;
our $foo = 'bar';

package main;

say $foo;        # bar
say $help::foo;  # bar

$help::foo = 'baz';

say $foo;        # baz
say $help::foo;  # baz

package BLOCK这在表单中不起作用，因为our将词汇别名限制为该块，即使包版本仍然存在（并且不限于该块）：

use v5.12;
use strict;
use warnings;

package help {
    our $foo = 'bar';
}

say $help::foo;  # bar

您可以指定完整的包规范，在这种情况下strict不再关心：

use v5.12;
use strict;

package help {
    $help::HELPTEXT{ "topic" } = "Some help";
}

或者，use vars：

use v5.12;
use strict;

package help {
    use vars qw(%HELPTEXT);
    $HELPTEXT{ "topic" } = "Some help";
}

你想help在顶部放一些包裹的东西，然后help在底部放一些更多的包裹。由于package只是更改了默认包，您可以再次使用它。也就是说，您不仅限于使用它一次，也不必将所有内容都放在第一个help块中：

use v5.12;
use strict;
use warnings;

package help {
    use vars qw(%HELPTEXT);

    sub help { $HELPTEXT{$_[0]} }
}

say "TOPIC: " . help::help("topic");

package help {
    use vars qw(%HELPTEXT);

    $HELPTEXT{ "topic" } = "Some help";
}

这不起作用，因为这些都是运行时语句。Perl 编译所有这些，但它会按顺序执行这些语句。这意味着$HELPTEXT{ "topic" } = "Some help";在您尝试使用它之后，直到最后才会运行。

ABEGIN解决了：

#!/usr/bin/perl
use v5.12;
use strict;
use warnings;

package help {
    use vars qw(%HELPTEXT);

    sub help { $HELPTEXT{$_[0]} }
}

say "TOPIC: " . help::help("topic");

BEGIN {
    package help {
        use vars qw(%HELPTEXT);

        $HELPTEXT{ "topic" } = "Some help";
    }
}

当 Perl 编译它时，它到达 BEGIN 块并编译它，然后立即运行它的块。包变量为%HELPTEXT已设置并可在程序中的任何位置使用。到顶部package help {}运行时，该哈希已设置。抛出一些消息可能更容易看到：

use v5.12;
use strict;
use warnings;

package help {
    use vars qw(%HELPTEXT);
    say "Setting up rest of help";

    sub help { $HELPTEXT{$_[0]} }
}

say "TOPIC: " . help::help("topic");

BEGIN {
    package help {
        use vars qw(%HELPTEXT);
        say "Setting up messages";
        $HELPTEXT{ "topic" } = "Some help";
    }
}

输出显示顺序。首先BEGIN运行，然后是脚本的顶部，然后是中间：

Setting up messages
Setting up rest of help
TOPIC: Some help

但是，如果你有一个词法变量，就会发生不同的事情。包变量在那里，但词法版本在其范围内时将其屏蔽：

use v5.12;
use strict;
use warnings;

$help::foo = 'quux';
say "Before: $help::foo";

package help {
    my $foo = 'bar';
    say "Inside: $foo";
}

say "After: $help::foo";

输出显示：

之前：quux 内部：bar 之后：quux

但是，请记住词法掩码只在块内。如果你呼唤不在那个范围内的东西，

use v5.12;
use strict;
use warnings;

$help::foo = 'quux';
say "Before: $help::foo";

package help {
    my $foo = 'bar';
    say "Inside: $foo";
    main::show_foo();
}

say "After: $help::foo";

sub show_foo { say "show_foo: $help::foo" }

输出显示，即使在块内调用，也会show_foo使用包版本，尽管子例程位于不同的包中：

Before: quux
Inside: bar
show_foo: quux
After: quux

因此，诀窍是要知道你的变量是词法的（受范围影响）还是包。

推荐阅读