zsh - zsh:拆分可能没有扩展名的路径
问题描述
在zsh
脚本中,我想将路径的文件名组件分成三部分:根、.
分隔符(可能不存在)和扩展名。另一个过程将修改这些部分并将它们重新组合在一起。
确定输入路径是否具有 a.
比预期的要复杂一些。到目前为止,这是我找到的最佳答案:
split=( "${path:r}" "${${path#${path:r}}:+.}" "${path:e}" )
它使用zsh
'sr
和e
参数标志来获取根和扩展名;这些部分运作良好。中间组件更神秘的扩展本质上是比较路径根和原始路径。如果它们相同,则没有分隔符并且值设置为空字符串。否则,它被设置为一个周期。
似乎应该有比三部分嵌套替换更简单的选择。是否有我遗漏的标志或简单的东西,或者我的搜索没有找到的 SO 帖子?
测试代码:
#!/bin/zsh
testsplit() {
local path=$1
local split=( "${path:r}" "${${path#${path:r}}:+.}" "${path:e}" )
print "input: [$path]"
print "split[${#split}]:" "[${(@)^split}]"
# tests: does rejoined path match input; is second element '.' or empty
[[ ${(j::)split} == $path && ${split[2]:-.} == '.' ]]
}
typeset -a testpaths=(
"base.ext"
"endsindot."
"no_ext"
"/a.b/c.d/e"
"/a.b/c.d/e."
"/a.b/c.d/e.f"
"/has/s p aces /before . after"
$"/*/'and?[sdf]\n>\t\tpat.tern[^r\`ty&]///*/notreal.d"
)
integer ecount=0
print '.'
for path in ${testpaths}; do
testsplit "$path"
(($?)) && ((++ecount)) && print "=== ERROR ==="
print '.'
done
print "Error count: [$ecount]."
((ecount)) && print "=== ERRORS FOUND ==="
输出:
.
input: [base.ext]
split[3]: [base] [.] [ext]
.
input: [endsindot.]
split[3]: [endsindot] [.] []
.
input: [no_ext]
split[3]: [no_ext] [] []
.
input: [/a.b/c.d/e]
split[3]: [/a.b/c.d/e] [] []
.
input: [/a.b/c.d/e.]
split[3]: [/a.b/c.d/e] [.] []
.
input: [/a.b/c.d/e.f]
split[3]: [/a.b/c.d/e] [.] [f]
.
input: [/has/s p aces /before . after]
split[3]: [/has/s p aces /before ] [.] [ after]
.
input: [$/*/'and?[sdf]
> pat.tern[^r`ty&]///*/notreal.d]
split[3]: [$/*/'and?[sdf]
> pat.tern[^r`ty&]///*/notreal] [.] [d]
.
Error count: [0].
解决方案
似乎应该有比三部分嵌套替换更简单的选择。
也许,但不幸的是,真的没有。
这是我的做法,但同样不能避免嵌套替换:
% split() {
local split=( "$1:r" "${${1#$1:r}[1]}" "$1:e" )
print "${(q@)split}"
}
% split foo.orig.c
foo.orig . c
% split dir.c/foo
dir.c/foo '' ''
推荐阅读
- android - Kotlin 将 html 从内部存储加载到 webview
- lua - 如何在 1 小时后将脚本停止到 C 堆栈溢出?
- sorting - 在飞镖中手动排序
- django - DRF 如何仅将第一个序列化对象返回到视图?
- javascript - 如何在功能组件 reactJS 中获得 for 循环
- python - SQLAlchemy在`load_only`内的列上使用`label`
- java - 使用 Spring + Thymeleaf 时获取 java.lang.StackOverflowError
- javascript - 如何迭代dict并使用map将其转换为react js中的表记录?
- sql - 在 Postgres 中修改 Jsonb 内部的字段
- postgresql - 无法将架构上的所有权限授予 postgresql 中的用户